Inno Setup : 이전에 설치된 버전을 자동으로 제거하는 방법은 무엇입니까?

Inno Setup : 이전에 설치된 버전을 자동으로 제거하는 방법은 무엇입니까?

---

Inno Setup을 사용하여 설치 프로그램을 만들고 있습니다.

설치 프로그램이 이전에 설치된 버전을 덮어 쓰지 않고 자동으로 제거하기를 원합니다. 어떻게 할 수 있습니까?

---

AppId (즉 AppID,- [Setup]섹션 에서 사용한 값)가 주어지면 레지스트리에서 제거 문자열을 읽을 수 있어야합니다 . 사용 된 실제 값으로 대체되어야하는 위치에서 찾을 수 있습니다 Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\( HKLM또는 HKCU일 수 있으므로 둘 다 선택하는 것이 가장 좋습니다) {AppId}. 를 찾아 UninstallString나 QuietUninstallString값과 사용 Exec하여에서 실행하는 기능을 InitializeSetup()이벤트 기능.

업데이트 : 이 문제를 지적한 모든 댓글 작성자 덕분에- [Run]섹션 항목을 사용하여 작동하지 않는 대체 솔루션을 제거 {uninstallexe}했습니다!

---

나는 다음을 사용했습니다. 가장 간단한 방법인지는 모르겠지만 효과가 있습니다.

이것은 {#emit SetupSetting("AppId")}Inno Setup Preprocessor에 의존하는 사용 입니다. 사용하지 않는 경우 앱 ID를 직접 잘라내어 붙여 넣습니다.

[Code]

/////////////////////////////////////////////////////////////////////
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


/////////////////////////////////////////////////////////////////////
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


/////////////////////////////////////////////////////////////////////
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
// Return Values:
// 1 - uninstall string is empty
// 2 - error executing the UnInstallString
// 3 - successfully executed the UnInstallString

  // default return value
  Result := 0;

  // get the uninstall string of the old app
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

/////////////////////////////////////////////////////////////////////
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

대안

한 단계 더 나아가 이전에 설치된 버전의 버전 번호를 읽고 현재 설치 패키지의 버전 번호와 비교하는 이 블로그 게시물 "Inno Setup Script Sample for Version Comparison" 을 참조하십시오 .

---

Inno Setup을 사용할 때 다른 설치 프로그램에서 해당 버전을 설치하지 않는 한 이전 버전을 제거 할 이유가 없습니다. 그렇지 않으면 업그레이드가 자동으로 처리됩니다.

---

"이전 아이콘을 제거하려면"(당신의 아이콘이 변경 / 업데이트 되었기 때문에) 다음을 사용할 수 있습니다.

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

이것은 "설치 시작시"실행되므로 기본적으로 이전 아이콘을 제거하고이 작업이 완전히 완료된 후에도 새 아이콘이 여전히 설치됩니다.

나는 "무엇이든 변경된 경우"아이콘을 현명하게 설치할 때마다이 작업을 수행합니다 (어쨌든 모두 다시 설치됩니다).

---

Craig McQueen이 제공 한 대답은 완전히 실행 가능합니다. 그러나 나는 그 주석을 추가 할 것이다.

• {#emit SetupSetting("AppId")}난 그냥 내 앱 ID를 추가 할 수 있도록 코드는 나를 위해 작동하지 않습니다.
• 제거 프로그램에 의해 제거 된 AppData / 폴더에 INI 구성 파일이 저장되어 있고 새 버전을 설치할 때 지워지는 것을 원하지 않기 때문에 제거 프로그램을 실행하고 싶지 않았습니다. 그래서 Craig McQueen이 제공 한 코드를 약간 수정하여 경로를 검색 한 후 프로그램이 설치된 디렉토리를 제거했습니다.

따라서 Craig McQueen의 코드와 관련하여 변경 사항은 다음과 같습니다.

• InstallLocation키 대신 키를 검색하십시오 UninstallString.
• DelTree대신 함수를 사용하십시오.Exec(sUnInstallString, ...)

---

GetUninstallString()위에서 제안한 방법 을 사용하여 내부 제거를 강제 CurStepChanged()하고 디스크 캐싱 문제가있는 사용자는 제거 프로그램 exe가 삭제 될 때까지 제거 후 실제로 잠시 대기하는 관련 솔루션을 아래에서 참조하십시오!

inno-setup에 디스크 캐싱 문제가 있습니까?

---

[code] 섹션에서 제거 프로그램을 실행할 수 있습니다. 기존 제거 프로그램의 경로를 얻는 방법을 알아 내야합니다. 간단하게 앱을 설치할 때 제거 프로그램이 포함 된 폴더를 가리키는 레지스트리 문자열 값을 추가하고 InitializeWizard 콜백에서 제거 프로그램을 실행합니다.

Inno 설치 제거 프로그램 이름은 모두 uninsnnn.exe 형식이므로 코드에서이를 고려해야합니다.

---

@Crain Mc-Queen 코드를 편집했습니다. 다른 프로젝트에서 수정할 필요가 없기 때문에이 코드가 더 좋다고 생각합니다.

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;

---

뭔가 빠졌 나봐요. 새로운 이전 설치의 제거가 발생하기 전에 파일을 대상 디렉토리에 복사됩니다. 그런 다음 제거 프로그램이 그들을 삭제하고 디렉토리를 제거합니다.

---

Do not use the [Run] section, but the [UninstallRun]. Infact, the program under [Run] are executed after the installation, causing to uninstall your program immediately after the installation :-| Instead, the [UninstallRun] section is evaluated before the installation.

---

Follow this link: http://news.jrsoftware.org/news/innosetup/msg55323.html

In InitializeSetup() function, you can call "MSIEXEC /x {your program ID}" after user prompt to uninstall old old version

참고URL : https://stackoverflow.com/questions/2000296/inno-setup-how-to-automatically-uninstall-previous-installed-version